; by unknown

/def -Fp2 -t'*trafia cie * w nogi* wyparowan*' stats_wyparowane_nogi = /dodaj_wyparowane nogi %{L1} 
/def -Fp2 -t'*trafia cie * w lewe ramie* wyparowan*' stats_wyparowane_lramie = /dodaj_wyparowane lramie %{L1}
/def -Fp2 -t'*trafia cie * w prawe ramie* wyparowan*' stats_wyparowane_pramie = /dodaj_wyparowane pramie %{L1}
/def -Fp2 -t'*trafia cie * w korpus* wyparowan*' stats_wyparowane_korpus = /dodaj_wyparowane korpus %{L1}
/def -Fp2 -t'*trafia cie * w glowe* wyparowan*' stats_wyparowane_glowa = /dodaj_wyparowane glowa %{L1}

/def -Fp2 -mregexp -t'.* trafia cie .* w .*, lecz caly impet uderzenia zostaje wyparowan.*' cos_ci_defensnelo_zbroja = /substitute -p @{C%c_bold}[zbr]@{n} %{P0}

/def -Fp2 -t'* cie w glowe.' stats_rany_glowa = /test ++glowa_rany
/def -Fp2 -t'* cie w lewe ramie.' stats_rany_lramie = /test ++lramie_rany
/def -Fp2 -t'* cie w prawe ramie.' stats_rany_pramie = /test ++pramie_rany
/def -Fp2 -t'* cie w korpus.' stats_rany_korpus = /test ++korpus_rany
/def -Fp2 -t'* cie w nogi.' stats_rany_nogi = /test ++nogi_rany

/def -Fp2 -mregexp -t'(.* udaje ci sie oslonic .*)' stats_oslona = /test ++oslona_tarcza%;/substitute -p @{C%c_bold}[tarcza]@{n} %{P1}
/def -Fp2 -mregexp -t'(.* tobie udaje sie oslonic .*)' stats_oslona2 = /test ++oslona_tarcza%;/substitute -p @{C%c_bold}[tarcza]@{n} %{P1}
/def -Fp2 -t'*, zbijajac uderzenie i momentalnie przechodzac do przeciwnatarcia.' stats_oslona4 = /test ++oslona_tarcza
/def -Fp2 -t'*, lecz ty zbijasz go *' stats_oslona5 = /test ++oslona_tarcza
/def -Fp2 -t'Wycwiczonym blokiem*odbijasz*' stats_oslona6 = /test ++oslona_tarcza
/def -Fp2 -t'W pore zaslaniasz sie*' stats_oslona7 = /test ++oslona_tarcza
/def -Fp2 -t'Skutecznie oslaniasz*' stats_oslona8 = /test ++oslona_tarcza
/def -Fp2 -t'Bez trudu zbijasz*' stats_oslona9 = /test ++oslona_tarcza

/def -Fp2 -mregexp -t'(.* tobie udaje sie uniknac .*)' stats_unk = /test ++unik%;/substitute -p @{C%c_bold}[unk]@{n} %{P1}
/def -Fp2 -mregexp -t'(.* nie udaje sie trafic ciebie .*)' stats_unk2 = /test ++unik%;/substitute -p @{C%c_bold}[unk]@{n} %{P1}
/def -Fp2 -t'*, lecz tobie udaje sie go uniknac.' stats_unik3 = /test ++unik
/def -Fp2 -t'*przecina powietrze tuz przed twoja glowa.' stats_unik4 = /test ++unik
/def -Fp2 -t'Z drwiacym usmiechem unikasz*' stats_unik5 = /test ++unik
/def -Fp2 -t'Z osiagnieta podczas lat treningu wprawa omijasz*' stats_unik6 = /test ++unik
/def -Fp2 -t'Efektownym wypadem schodzisz*' stats_unik7 = /test ++unik
/def -Fp2 -t'Z pokazowa latwoscia unikasz*' stats_unik8 = /test ++unik

/def -Fp2 -mregexp -t'(.* tobie udaje sie je zbic.*)' stats_parowanie = /test ++parowanie%;/substitute -p @{C%c_bold}[par]@{n} %{P1}
/def -Fp2 -mregexp -t'(.*, lecz tobie udaje sie zbic je z linii ataku.*)' stats_parowanie2 = /test ++parowanie%;/substitute -p @{C%c_bold}[par]@{n} %{P1}
/def -Fp2 -mregexp -t'(.*, lecz tobie udaje sie go sparowac.*)' stats_parowanie3 = /test ++parowanie%;/substitute -p @{C%c_bold}[par]@{n} %{P1}
/def -Fp2 -mregexp -t'(W pore zakleszczasz cios.*)' stats_parowanie4 = /test ++parowanie%;/substitute -p @{C%c_bold}[par]@{n} %{P1}
/def -Fp2 -t'*, lecz sprawnie parujesz go*' stats_parowanie5 = /test ++parowanie
/def -Fp2 -t'Odpierasz natarcie*blyskawiczna zaslona*' stats_parowanie6 = /test ++parowanie
/def -Fp2 -t'Efektownie parujesz*' stats_parowanie7 = /test ++parowanie
/def -Fp2 -t'Jak gdyby od niechcenia zbijasz*' stats_parowanie8 = /test ++parowanie
/def -Fp2 -t'Elegancko odbijasz cios*' stats_parowanie9 = /test ++parowanie

/def -Fp2 -t'*dotknal cie w glowe *' stats_rany_glowa2 = /test ++glowa_rany
/def -Fp2 -t'*dotknal cie w lewe ramie *' stats_rany_lramie2 = /test ++lramie_rany
/def -Fp2 -t'*dotknal cie w prawe ramie *' stats_rany_pramie2 = /test ++pramie_rany
/def -Fp2 -t'*dotknal cie w korpus *' stats_rany_korpus2 = /test ++korpus_rany
/def -Fp2 -t'*dotknal cie w nogi *' stats_rany_nogi2 = /test ++nogi_rany

/def -Fp2 -mregexp -t'Wykorzystujac brak broni .* (ze swistem|zbijajac w pore)' stats_spec_0 = /test ++spec_0
/def -Fp2 -mregexp -t'Wykorzystujac brak broni .* (ledwie zahaczajac|ledwie sinca)' stats_spec_1 = /test ++spec_1
/def -Fp2 -mregexp -t'Wykorzystujac brak broni .* (lekko raniac|krwawiace zadrapanie)' stats_spec_2 = /test ++spec_2
/def -Fp2 -mregexp -t'Wykorzystujac brak broni .* (mocno raniac|dluga, poszarpana rane)' stats_spec_3 = /test ++spec_3
/def -Fp2 -mregexp -t'Wykorzystujac brak broni .* (bardzo mocno raniac|gleboka rane z wystajacymi)' stats_spec_4 = /test ++spec_4
/def -Fp2 -mregexp -t'Wykorzystujac brak broni .* smiertelne obrazenia' stats_spec_5 = /test ++spec_5

/def -Fp2 -mregexp -t'ktory ma zmasakrowac.* twoja bron jakims cudem ' stats_spec_0 = /test ++spec_0
/def -Fp2 -mregexp -t'rzucasz sie do ataku.* (ledwo muskajac) ' stats_spec_1 = /test ++spec_1
/def -Fp2 -mregexp -t'rzucasz sie do ataku.* (lekko raniac) ' stats_spec_2 = /test ++spec_2
/def -Fp2 -mregexp -t'rzucasz sie do ataku.* ((?<!lekko |powaznie |bardzo ciezko )raniac) ' stats_spec_3 = /test ++spec_3
/def -Fp2 -mregexp -t'rzucasz sie do ataku.* (powaznie raniac) ' stats_spec_4 = /test ++spec_4
/def -Fp2 -mregexp -t'rzucasz sie do ataku.* (bardzo ciezko raniac) ' stats_spec_5 = /test ++spec_5
/def -Fp2 -mregexp -t'rzucasz sie do ataku.* (masakrujac) ' stats_spec_6 = /test ++spec_6
/def -Fp2 -mregexp -t'Stajesz pewnie na szeroko rozstawionych nogach' stats_spec_7 = /test ++spec_7

/def dodaj_wyparowane = \
  /let co=$[replace(".","",{2})]%;\
  /test (wyparowane_%{1}_%{co}:=wyparowane_%{1}_%{co} + 1)%;

/def stats_wyparowane = \
  /let j=%{1}%;\
  /let wyp_razem=0%;\
  /let wyparowane_lista=$(/listvar -s -mglob wyparowane_%{j}_*)%;\
  /let wyparowane_lista=$[strcat(wyparowane_lista," end")]%;\
  /let linia=%;\
  /while /let i=$[strstr(wyparowane_lista," ")]%; /@test i>0%;/do \
    /let sprzet=$[substr(wyparowane_lista,0,i)]%;\
    /let wyparowane_lista=$[substr(wyparowane_lista,i+1)]%;\
    /let wyp_ile=$(/listvar -v %{sprzet})%;\
    /let wyp_razem=$[wyp_razem+wyp_ile]%;\
    /let sprzet_nazwa=$[substr(sprzet,strrchr(sprzet,"_")+1)]%;\
    /let linia=$[strcat(linia," ",sprzet_nazwa,":",wyp_ile,"  ")]%;\
  /done%;\
  /let procent=100%;\
  /let x=$(/listvar -v %{j}_rany)%;\
  /let x=$[wyp_razem+x]%;\
  /set wszystkie_parowania=$[wszystkie_parowania+wyp_razem]%;\
  /if ({x}>0) \
    /let procent=$[100*wyp_razem / x ]%;\
  /else \
    /let procent=?%;\
  /endif%;\
  /let linia=$[strcat("| ",pad(j,-6)," ",pad(wyp_razem,5),"/",pad(x,-5)," [",pad(procent,3),"%%]  |",linia)]%;\
  /eval /echo -p %{linia}@{n}

/def stats =\
  /set wszystkie_parowania=0%;\
  /echo -p +----[ Skutecznosc zbroi ]---+-----------[ Wyparowane przez ]---------+@{n}%;\
  /stats_wyparowane glowa%;\
  /stats_wyparowane lramie%;\
  /stats_wyparowane pramie%;\
  /stats_wyparowane korpus%;\
  /stats_wyparowane nogi%;\
  /echo -p +----------------------------+----------------------------------------+@{n}%;\
  /test (wszystkie_rany:=glowa_rany+lramie_rany+pramie_rany+korpus_rany+nogi_rany)%;\
  /let x=$[wszystkie_parowania+wszystkie_rany+unik+oslona_tarcza+parowanie]%;\
  /let spece_suma=$[spec_0+spec_1+spec_2+spec_3+spec_4+spec_5+spec_6+spec_7]%;\
  /if (x>0) \
    /let p1=$[100*unik / x]%;\
    /let p2=$[100*parowanie / x]%;\
    /let y=$[wszystkie_parowania+unik+oslona_tarcza+parowanie]%;\
    /let p3=$[100*oslona_tarcza / x]%;\
    /let p4=$[100*y / x]%;\
  /else \
    /let p1=?%;\
    /let p2=?%;\
    /let p3=?%;\
    /let p4=?%;\
  /endif%;\
  /if (spece_suma>0) \
    /let ppp0=$[100*spec_0 / spece_suma]%;\
    /let ppp1=$[100*spec_1 / spece_suma]%;\
    /let ppp2=$[100*spec_2 / spece_suma]%;\
    /let ppp3=$[100*spec_3 / spece_suma]%;\
    /let ppp4=$[100*spec_4 / spece_suma]%;\
    /let ppp5=$[100*spec_5 / spece_suma]%;\
    /let ppp5=$[100*spec_6 / spece_suma]%;\
    /let ppp5=$[100*spec_7 / spece_suma]%;\
    /let ppp8=$[100*spece_suma / (ilosc_ciosow+spece_suma)]%;\
  /else \
    /let ppp0=?%;\
    /let ppp1=?%;\
    /let ppp2=?%;\
    /let ppp3=?%;\
    /let ppp4=?%;\
    /let ppp5=?%;\
    /let ppp6=?%;\
    /let ppp7=?%;\
    /let ppp8=0%;\
  /endif%;\
  /if ({_rozkaz_udany} > 0) \
    /let p6=$[100*_rozkaz_udany/ (_rozkaz_nieudany+_rozkaz_udany)]%;\
  /else \
    /let p6=?%;\
  /endif%;\
  /let linia=$[strcat("| ",pad("uniki",-6)," ",pad(unik,5),"/",pad(x,-5)," [",pad(p1,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("zbicia",-6)," ",pad(parowanie,5),"/",pad(x,-5)," [",pad(p2,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("oslona",-6)," ",pad(oslona_tarcza,5),"/",pad(x,-5)," [",pad(p3,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("rozkaz",-6)," ",pad(_rozkaz_udany,5),"/",pad(_rozkaz_nieudany,-5)," [",pad(p6,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("+----[ Statystyka specow ]---+")]%;\
  /let linia=$[strcat(linia,"-----[ W sumie: ",pad(y,5),"/",pad(x,-5)," [",decode_attr(pad(p4,3), {zc_info}),"@{C%c_info}%%@{n}] ]----+")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("Spec 0/7",-6)," ",pad(spec_0,3),"/",pad(spece_suma,-5)," [",pad(ppp0,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("Spec 1/7",-6)," ",pad(spec_1,3),"/",pad(spece_suma,-5)," [",pad(ppp1,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("Spec 2/7",-6)," ",pad(spec_2,3),"/",pad(spece_suma,-5)," [",pad(ppp2,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("Spec 3/7",-6)," ",pad(spec_3,3),"/",pad(spece_suma,-5)," [",pad(ppp3,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("Spec 4/7",-6)," ",pad(spec_4,3),"/",pad(spece_suma,-5)," [",pad(ppp4,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("Spec 5/7",-6)," ",pad(spec_5,3),"/",pad(spece_suma,-5)," [",pad(ppp5,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("Spec 6/7",-6)," ",pad(spec_6,3),"/",pad(spece_suma,-5)," [",pad(ppp5,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("| ",pad("Spec 7/7",-6)," ",pad(spec_7,3),"/",pad(spece_suma,-5)," [",pad(ppp5,3),"%%]  |")]%;\
  /eval /echo -p %{linia}@{n}%;\
  /let linia=$[strcat("+----------------------------+")]%;\
  /eval /echo -p %{linia}@{n}%;\

/def czysc_staty = \
  /quote -S /unset `/listvar -s wyparowane_*%;\
  /quote -S /unset `/listvar -s *_rany%;\
  /quote -S /unset `/listvar -s unik%;\
  /quote -S /unset `/listvar -s oslona_tarcza%;\
  /quote -S /unset `/listvar -s parowanie%;\

/def czysc_spece = /quote -S /unset `/listvar -s spec_*%;

; postepy
/set _postepy_max=16
/set _postepy_list=\
  logowanie|\
  minimalne|\
  nieznaczne|\
  bardzo male|\
  male|\
  nieduze|\
  zadowalajace|\
  spore|\
  dosc duze|\
  znaczne|\
  duze|\
  bardzo duze|\
  ogromne|\
  imponujace|\
  wspaniale|\
  gigantyczne|\
  niebotyczne

; by Ingwar

/def exp = \
    /send cechy %;\
    /send usiadz %;\
    /send medytuj %;\
    /send ocen cechy %;\
    /send powstan

/def _cechy_trigs = \
    /purge _cechy_set_* %;\
    /rstart -5 2 /purge _cechy_set_* %;\
    /def -a -p5 -t'*Jestes *{krasnoludem,|krasnoludka,}*' _cechy_set_race_1=/set ogolne_cechy_rasa 1%;\
    /def -a -p5 -t'*Jestes *{elfka,|elfem,}*' 		_cechy_set_race_2=/set ogolne_cechy_rasa 2%;\
    /def -a -p5 -t'*Jestes *{mezczyzna,|kobieta,}*' 	_cechy_set_race_3=/set ogolne_cechy_rasa 3%;\
    /def -a -p5 -t'*Jestes *{halflingiem,|halflinka,}*' _cechy_set_race_4=/set ogolne_cechy_rasa 4%;\
    /def -a -p5 -t'*Jestes *{gnomem,|gnomka,}*' 	_cechy_set_race_5=/set ogolne_cechy_rasa 5%;\
    /def -a -p5 -t'*Jestes *{ogrem,|ogrzyca,}*' 	_cechy_set_race_6=/set ogolne_cechy_rasa 6%;\
    /def -a -p5 -t'*Jestes *{polelfem,|polelfka,}*' 	_cechy_set_race_7=/set ogolne_cechy_rasa 7%;\
    %;\
    /def -FP -p4 -t' slabiutk' 				_cechy_set_str_1=/set ogolne_cechy_cecha1 1 %;\
    /def -FP -p4 -t' watl' 				_cechy_set_str_2=/set ogolne_cechy_cecha1 2 %;\
    /def -FP -p5 -t' slab' 				_cechy_set_str_3=/set ogolne_cechy_cecha1 3 %;\
    /def -FP -p4 -t' krzepk' 				_cechy_set_str_4=/set ogolne_cechy_cecha1 4 %;\
    /def -FP -p4 -t' siln' 				_cechy_set_str_5=/set ogolne_cechy_cecha1 5 %;\
    /def -FP -p4 -t' mocn' 				_cechy_set_str_6=/set ogolne_cechy_cecha1 6 %;\
    /def -FP -p4 -t' potezn' 				_cechy_set_str_7=/set ogolne_cechy_cecha1 7 %;\
    /def -FP -p4 -t' mocarn' 				_cechy_set_str_8=/set ogolne_cechy_cecha1 8 %;\
    %;\
    /def -FP -p4 -t' nieskoordynowan' 			_cechy_set_dex_1=/set ogolne_cechy_cecha2 1 %;\
    /def -FP -p4 -t' niezreczn' 		       	_cechy_set_dex_2=/set ogolne_cechy_cecha2 2 %;\
    /def -FP -p4 -t' niezgrabn' 			       _cechy_set_dex_3=/set ogolne_cechy_cecha2 3 %;\
    /def -FP -p4 -t' sprawn' 				_cechy_set_dex_4=/set ogolne_cechy_cecha2 4 %;\
    /def -FP -p4 -t' zwinn' 				_cechy_set_dex_5=/set ogolne_cechy_cecha2 5 %;\
    /def -FP -p4 -t' zreczn' 				_cechy_set_dex_6=/set ogolne_cechy_cecha2 6 %;\
    /def -FP -p4 -t' gibk' 				_cechy_set_dex_7=/set ogolne_cechy_cecha2 7 %;\
    /def -FP -p4 -t' akrobatyczn' 			_cechy_set_dex_8=/set ogolne_cechy_cecha2 8 %;\
    %;\
    /def -FP -p4 -t' cherlaw' 				_cechy_set_con_1=/set ogolne_cechy_cecha3 1 %;\
    /def -FP -p4 -t' rachityczn' 			       _cechy_set_con_2=/set ogolne_cechy_cecha3 2 %;\
    /def -FP -p4 -t' mizern' 				_cechy_set_con_3=/set ogolne_cechy_cecha3 3 %;\
    /def -FP -p4 -t' dobrze zbudowan' 			_cechy_set_con_4=/set ogolne_cechy_cecha3 4 %;\
    /def -FP -p4 -t' wytrzymal' 		       	_cechy_set_con_5=/set ogolne_cechy_cecha3 5 %;\
    /def -FP -p4 -t' tward' 				_cechy_set_con_6=/set ogolne_cechy_cecha3 6 %;\
    /def -FP -p4 -t' muskularn' 		   		_cechy_set_con_7=/set ogolne_cechy_cecha3 7 %;\
    /def -FP -p4 -t' atletyczn' 				_cechy_set_con_8=/set ogolne_cechy_cecha3 8 %;\
    %;\
    /def -FP -p4 -t' bezmysln' 				_cechy_set_int_1=/set ogolne_cechy_cecha4 1 %;\
    /def -FP -p4 -t' tepa| tepy' 				_cechy_set_int_2=/set ogolne_cechy_cecha4 2 %;\
    /def -FP -p4 -t' ograniczon' 				_cechy_set_int_3=/set ogolne_cechy_cecha4 3 %;\
    /def -FP -p4 -t' pojetn' 				_cechy_set_int_4=/set ogolne_cechy_cecha4 4 %;\
    /def -FP -p4 -t' inteligentn' 			_cechy_set_int_5=/set ogolne_cechy_cecha4 5 %;\
    /def -FP -p4 -t' bystr' 				_cechy_set_int_6=/set ogolne_cechy_cecha4 6 %;\
    /def -FP -p4 -t' blyskotliw' 				_cechy_set_int_7=/set ogolne_cechy_cecha4 7 %;\
    /def -FP -p4 -t' genialn' 				_cechy_set_int_8=/set ogolne_cechy_cecha4 8 %;\
    %;\
    /def -FP -p4 -t' glupi' 				_cechy_set_wis_1=/set ogolne_cechy_cecha5 1 %;\
    /def -FP -p4 -t' zacofan' 				_cechy_set_wis_2=/set ogolne_cechy_cecha5 2 %;\
    /def -FP -p4 -t' niewyksztalcon' 			_cechy_set_wis_3=/set ogolne_cechy_cecha5 3 %;\
    /def -FP -p4 -t' wyksztalcon' 			_cechy_set_wis_4=/set ogolne_cechy_cecha5 4 %;\
    /def -FP -p4 -t' madr' 				_cechy_set_wis_5=/set ogolne_cechy_cecha5 5 %;\
    /def -FP -p4 -t' uczon' 				_cechy_set_wis_6=/set ogolne_cechy_cecha5 6 %;\
    /def -FP -p4 -t' oswiecon' 				_cechy_set_wis_7=/set ogolne_cechy_cecha5 7 %;\
    /def -FP -p4 -t' wszechwiedzac' 			_cechy_set_wis_8=/set ogolne_cechy_cecha5 8 %;\
    %;\
    /def -FP -p4 -t'tchorzliw' 				_cechy_set_dis_1=/set ogolne_cechy_cecha6 1 %;\
    /def -FP -p4 -t'strachliw' 				_cechy_set_dis_2=/set ogolne_cechy_cecha6 2 %;\
    /def -FP -p4 -t'niepewn' 				_cechy_set_dis_3=/set ogolne_cechy_cecha6 3 %;\
    /def -FP -p4 -t'zdecydowan' 				_cechy_set_dis_4=/set ogolne_cechy_cecha6 4 %;\
    /def -FP -p4 -t'odwazn' 				_cechy_set_dis_5=/set ogolne_cechy_cecha6 5 %;\
    /def -FP -p4 -t'dzieln' 				_cechy_set_dis_6=/set ogolne_cechy_cecha6 6 %;\
    /def -FP -p4 -t'nieugiet' 				_cechy_set_dis_7=/set ogolne_cechy_cecha6 7 %;\
    /def -FP -p4 -t'nieustraszon' 			_cechy_set_dis_8=/set ogolne_cechy_cecha6 8 %;\
    %;\
    /def -p5 -P -t'ze bardzo duzo ci brakuje' 		_cechy_set_brak_1=/set cechy_brakuje 5%%;/_cechy_liczenie %;\
    /def -p5 -P -t'ze duzo ci brakuje' 			_cechy_set_brak_2=/set cechy_brakuje 4%%;/_cechy_liczenie %;\
    /def -p5 -P -t'ze troche ci brakuje' 		_cechy_set_brak_3=/set cechy_brakuje 3%%;/_cechy_liczenie %;\
    /def -p5 -P -t'ze niewiele ci brakuje' 		_cechy_set_brak_4=/set cechy_brakuje 2%%;/_cechy_liczenie %;\
    /def -p5 -P -t'ze bardzo niewiele ci brakuje'	_cechy_set_brak_5=/set cechy_brakuje 1%%;/_cechy_liczenie %;\
    /def -p5 -P -t'epicka' 				_cechy_set_brak_6=/set cechy_brakuje 9%%;/_cechy_liczenie %;\
    /def -p5 -P -t'nadludzk' 				_cechy_set_brak_7=/set cechy_brakuje 10%%;/_cechy_liczenie %;\
    %;\
    /set cechy_brakuje 0 %;\
    /set cechy_licznik 0 %;\
    /if ({ogolne_cechy_rasa}=~NULL) \
       /send spojrz na siebie %;\
    /endif %;\
    /send cechy %;\
    /send usiadz %;\
    /send medytuj %;\
    /send ocen sile %;\
    /send ocen zrecznosc %;\
    /send ocen wytrzymalosc %;\
    /send ocen inteligencje %;\
    /send ocen madrosc %;\
    /send ocen odwage %;\
    /send powstan

/def _cechy_liczenie=\
  /test ++cechy_licznik %;\
;  /purge _cechy_set_* %;\
  /if ({cechy_brakuje}==9 | {cechy_brakuje}==10) \
    /set ogolne_cechy_cecha%{cechy_licznik} %{cechy_brakuje}  %;\
    /set ogolne_cechy_brak%{cechy_licznik} 0 %;\
  /else \
    /set ogolne_cechy_brak%{cechy_licznik} %{cechy_brakuje} %;\
  /endif %;\
  /if ({cechy_licznik}==6) \
    /repeat -0 1 /_cechy %;\
    /unset cechy_licznik %;\
    /unset cechy_brakuje %;\
    /purge _cechy_set_* %;\
  /endif

/def _cechy_poziom_one = \
    /eval /return {$[{1} + 1]}

/def _cechy_poziom = \
    /let _opis=$[_cechy_poziom_one({1}, \
    'kompletnego zoltodzioba', \
    'stawia pierwsze kroki', \
    'jeszcze niewiele widzial', \
    'niewiele wie o swiecie', \
    'niedoswiadczonego', \
    'widzial juz to i owo', \
    'pewnie stapa po swiecie', \
    'niejedno widzial', \
    'swoje przezyl', \
    'doswiadczonego', \
    'wiele przeszedl', \
    'widzial kawal swiata', \
    'bardzo doswiadczonego', \
    'zwiedzil caly swiat', \
    'wielce doswiadczonego', \
    'widzial i doswiadczyl wszystkiego', \
    'osobe owiana legenda')] %;\
    /return strcat("Szacowany poziom: ", decode_attr(_opis, {zc_info}), " (", {1}, "/17)")


/def _cechy_licz = \
    /let _poziom=%{1} %;\
    /let _brakuje=%{2} %;\
    /if (_poziom == 10) \
        /let _punkty=160 %;\
    /elseif (_poziom == 9) \
        /let _punkty=136 %;\
    /else \
            /let _punkty=$[((_poziom - 1) * 17) + ((5 - _brakuje) * 3) + ((5 - _brakuje + 1) / 2)] %;\
    /endif %;\
    /return %{_punkty}

/def _cechy = \
    /let _str=$[_cechy_licz(ogolne_cechy_cecha1, ogolne_cechy_brak1)] %;\
    /let _dex=$[_cechy_licz(ogolne_cechy_cecha2, ogolne_cechy_brak2)] %;\
    /let _con=$[_cechy_licz(ogolne_cechy_cecha3, ogolne_cechy_brak3)] %;\
    /let _int=$[_cechy_licz(ogolne_cechy_cecha4, ogolne_cechy_brak4)] %;\
    /let _wis=$[_cechy_licz(ogolne_cechy_cecha5, ogolne_cechy_brak5)] %;\
    /let _dis=$[_cechy_licz(ogolne_cechy_cecha6, ogolne_cechy_brak6)] %;\
    /let _sum=$[_str + _dex + _con + _int + _wis + _dis] %;\
    /let _avg=$[_sum / 6] %;\
    /let _avg_c=$[(_str + _dex + _con) / 3] %;\
    /let _avg_nc=$[(_int + _wis + _dis) / 3] %;\
; wg Grrida (niebardzo dobrze;/)
;    /let _div=48 %;\
;    /let _need=$[_div - mod(_sum, _div)] %;\
;    /let _need_p=$[trunc(_need / 3.5)] %;\
;    /let _level=$[trunc(_sum / _div) + 1] %;\
; troszeczke zmodyfikowane
    /let _div=48 %;\
    /let _need=$[_div - mod(_sum-5, _div)] %;\
    /let _need_p=$[trunc(_need / 3.5)] %;\
    /let _level=$[trunc((_sum-5)/ _div) + 1] %;\
;-------------------------------------
    /let _szer=$[80 / 6 - 2] %;\
    /test echo(strcat("+", strrep("-", {_szer} * 6 + 11), "+")) %;\
    /test echo(pad("|                  ", 0, \
        " Str ", 4, " |", 0, \
        " Dex ", 4, " |", 0, \
        " Con ", 4, " |", 0, \
        " Int ", 4, " |", 0, \
        " Wis ", 4, " |", 0, \
        " Dis ", 4, "                   |", 0)) %;\
    /test echo(pad("|                  ", 0, \
        decode_attr(_str, {zc_info}), 4, "  |", 0, \
        decode_attr(_dex, {zc_info}), 4, "  |", 0, \
        decode_attr(_con, {zc_info}), 4, "  |", 0, \
        decode_attr(_int, {zc_info}), 4, "  |", 0, \
        decode_attr(_wis, {zc_info}), 4, "  |", 0, \
        decode_attr(_dis, {zc_info}), 4, "                    |", 0)) %;\
    /test echo(strcat("+", strrep("-", {_szer} * 6 + 11), "+")) %;\
    /test echo(strcat("| ", pad(_cechy_poziom({_level}), -({_szer} * 6 + 10)), "+")) %;\
    /test echo(strcat("+", strrep("-", {_szer} * 6 + 11), "+")) %;\
    /test echo(pad("| ", 0, \
        "Srednia:  ", 0, \
        decode_attr(_avg, {zc_info}), 3, \
        ", bojowki: ", 0, \
        decode_attr(_avg_c, {zc_info}), 3, \
        ", mentale: ", 0, \
        decode_attr(_avg_nc, {zc_info}), 3, \
        ", wspolczynnik: ", 0, \
        decode_attr($[(1.0 * _avg_c) / _avg_nc], {zc_info}), -13, \
        "|", 4)) %;\
    /test echo(pad("| ", 0, \
        "Podcechy: ", 0, \
        decode_attr($[trunc(_sum / 3.33)], {zc_info}), 3, \
        ", brakuje: ", 0, \
        decode_attr(_need_p, {zc_info}), -2, \
        "|", 51)) %;\
    /test echo(strcat("+", strrep("-", {_szer} * 6 + 11), "+"))