/def _walk_binds = \
  /def key_nkp/ = /sneak off %;\
  /def key_nkp* = /sneak ON %;\
  /def key_nkp- = /sneak GRP %;\
  /if ( {ktype} =~ "mac" ) \
    /def key_f13 = /sneak off %;\
    /def key_f14 = /sneak ON %;\
    /def key_f15 = /sneak GRP %;\
  /endif
/_walk_binds

/def wns = \
  /if ( {hide} =~ "on" )\
    /send ujawnij sie %;\
  /endif%;\
  /if ( {pack} =~ "on" )\
    /zp monety %;\
  /endif%;\
  /send kup bilet%;\
  /send wejdz na statek%;\
  /if ( {pack} =~ "on" )\
    /dp monety %;\
  /endif
/alias wns /wns

/def wdyl = \
  /if ( {hide} =~ "on" )\
    /send ujawnij sie %;\
  /endif%;\
  /if ( {pack} =~ "on" )\
    /zp monety %;\
  /endif%;\
  /send wsiadz do dylizansu %;\
  /if ( {pack} =~ "on" )\
    /dp monety %;\
  /endif
/alias wdyl /wdyl

/def skroc_kierunek =\
  /eval /set v=%dlugi_kierunek%;\
  /set v=$[replace("polnocny-","n",v)]%;\
  /set v=$[replace("poludniowy-","s",v)]%;\
  /set v=$[replace("polnoc","n",v)]%;\
  /set v=$[replace("poludnie","s",v)]%;\
  /set v=$[replace("wschod","e",v)]%;\
  /set v=$[replace("zachod","w",v)]%;\
  /set v=$[replace("gore","u",v)]%;\
  /set v=$[replace("gora","u",v)]%;\
  /set v=$[replace("dol","d",v)]%;\
  /eval /set krotki_kierunek=%{v}%;\
  /set lwgo=0

/def walkcmd = \
  /if ({1} =~ "off")\
    /set dowalkcmd=0%;\
    /set walkcmd=none%;\
  /elseif ({1} =~ "")\
    /echo -p #@{C%c_info}#@{n}# walkcmd: @{C%c_info}%{walkcmd}@{n}%;\
  /else \
    /set dowalkcmd=1%;\
    /set walkcmd=%*%;\
    /set lastmapon=%{_map_on}%;\
    /load %{main_dir}/common/map.tf%;\
    /set _map_on=%{lastmapon}%;\
  /endif

/def idz = \
  /if ({sneak} =~ "off" )\
    /send -h %{1} %;\
  /elseif ({sneak} =~ "ON" )\
    /send -h przemknij %{1} %;\
  /elseif ({sneak} =~ "GRP" )\
    /send -h przemknij z druzyna %{1}%;\
  /endif

/def lw4=\
  /for a 0 12 /eval /unset _lw%%a %;\
  /set lwcount=0%;\
  /set lw=%lw,%;\
  /set lw2=%;\
  /while (lw!~"") /lw5%; /done%;\
  /set lw2=$[strcat(_lw0,_lw1,_lw2,_lw3,_lw4,_lw5,_lw6,_lw7,_lw8,_lw9,_lw10,_lw11,_lw12)]%;\
  /set exits=$[substr(lw2,0,strlen(lw2)-1)]%;\
  /checkgo

/def -mregexp -Fp2 -t'(Ruszasz .* na (.*)|podazasz .*za .* na (.*))\\.' ide_sobie = \
  /if ({P2} =~ "polnoc" ) /set lwlast=n%;\
  /elseif ({P2} =~ "poludnie" ) /set lwlast=s%;\
  /elseif ({P2} =~ "zachod" ) /set lwlast=w%;\
  /elseif ({P2} =~ "wschod" ) /set lwlast=e%;\
  /elseif ({P2} =~ "polnocny-zachod" ) /set lwlast=nw%;\
  /elseif ({P2} =~ "polnocny-wschod" ) /set lwlast=ne%;\
  /elseif ({P2} =~ "poludniowy-zachod" ) /set lwlast=sw%;\
  /elseif ({P2} =~ "poludniowy-wschod" ) /set lwlast=se%;\
  /elseif ({P2} =~ "gore" ) /set lwlast=u%;\
  /elseif ({P2} =~ "dol" ) /set lwlast=d%;\
  /else /set lwlast=X%;\
  /endif

/def unnormalset = \
  /alias ww /dounnormal %{*} %%; /set lwlast=dziwne %;\
  /echo -p #@{C%c_info}#@{n}# Dziwne wyjscie - @{C%c_info}%{*}@{n}.

/def dounnormal = \
  /if ( {sneak} =~ "ON" )\
    /send -h przemknij %{*}%;\
  /elseif ( {sneak} =~ "GRP" )\
    /send -h przemknij z druzyna %{*}%;\
  /else \
    /send -h %{*}%;\
  /endif

/def checkgo=\
  /if (lwgo==1)\
    /if (lwcount==2)\
      /def key_f12  = /testujwyjscia%;\
      /def key_nkp5 = /testujwyjscia%;\
      /else \
        /set lwgo=0%;\
      /endif%;\
    /endif

/def testujwyjscia=\
  /if ((_lw0!~"") & (lwlast!~"e"))      /set lwlast=w%; w%;\
  /elseif ((_lw1!~"") & (lwlast!~"se")) /set lwlast=nw%; nw%;\
  /elseif ((_lw2!~"") & (lwlast!~"s"))  /set lwlast=n%; n%;\
  /elseif ((_lw3!~"") & (lwlast!~"sw")) /set lwlast=ne%; ne%;\
  /elseif ((_lw4!~"") & (lwlast!~"w"))  /set lwlast=e%; e%;\
  /elseif ((_lw5!~"") & (lwlast!~"nw")) /set lwlast=se%; se%;\
  /elseif ((_lw6!~"") & (lwlast!~"n"))  /set lwlast=s%; s%;\
  /elseif ((_lw7!~"") & (lwlast!~"ne")) /set lwlast=sw%; sw%;\
  /elseif ((_lw8!~"") & (lwlast!~"d"))  /set lwlast=u%; u%;\
  /elseif ((_lw9!~"") & (lwlast!~"u"))  /set lwlast=d%; d%;\
  /else \
    /beep 1 %;\
    /set lwgo=0%;\
  /endif%;\
  /def key_f12%;\
  /def key_nkp5

/def -i -b'Ol' = /key_nkp+
/def key_nkp8 = /idz n
/def key_nkp2 = /idz s
/def key_nkp4 = /idz w
/def key_nkp6 = /idz e
/def key_nkp7 = /idz nw
/def key_nkp9 = /idz ne
/def key_nkp1 = /idz sw
/def key_nkp3 = /idz se
/def key_nkp+ = /idz u
/def key_nkp. = /idz d

/def sneak = \
  /if ( {1} =~ "off" ) \
    /set sneak %{1} %;\
    /status_edit -r2 sneak:3:C%{c_main} %;\
  /elseif ( {1} =~ "ON" ) \
    /set sneak %{1} %;\
    /status_edit -r2 sneak:3:C%{c_alarm} %;\
  /elseif ( {1} =~ "GRP" ) \
    /set sneak %{1} %;\
    /status_edit -r2 sneak:3:C%{c_alarm} %;\
  /else \
    /echo -p #@{C%c_info}#@{n}# sneak: @{C%c_info}%{sneak}@{n}%;\
  /endif

/def hideup = \
  /if ({hideshow} < "15" )\
    /test ++hideshow%;\
    /status_edit -r1 hideshow:3:C%c_alarm%;\
    /repeat -1 1 /hideup %;\
  /endif

/def hide = \
  /if ( {1} =~ "off" ) \
    /set hide %{1} %;\
    /set hideshow %{1} %;\
    /status_edit -r1 hideshow:3:C%{c_main} %;\
    /rstop hideup %;\
  /elseif ( {1} =~ "on" ) \
    /set hide %{1} %;\
    /set hideshow 0%;\
    /status_edit -r1 hideshow:3:C%{c_alarm} %;\
    /rstop hideup %;\
    /repeat -1 1 /hideup %;\
  /endif

/def -mregexp -Fp2 -t'Chowasz sie .* potrafisz' hideon0 = /hide on
/def -mregexp -Fp2 -t'Nie potrafisz ukryc sie jeszcze bardziej' hideon1 = /hide on
/def -mregexp -Fp2 -t'podazasz skradajac sie za ' hideon2 = /hide on
/def -mregexp -Fp2 -t'.* ujawnia cie.*' hideoff0 = /hide off
/def -mregexp -Fp2 -t'Nie jestes juz schowan.' hideoff1 = /hide off
/def -mregexp -Fp2 -t'Nie jestes w stanie sie tu dobrze schowac' hideoff2 = /hide off
/def -mregexp -Fp2 -t'Wychodzisz z ukrycia' hideoff3 = /hide off
/def -mregexp -Fp2 -t'Przeciez nie jestes ukryt' hideoff4 = /hide off
/def -mregexp -Fp2 -t'Jest tu zbyt ciezko sie schowac' hideoff5 = /hide off
/def -mregexp -Fp2 -t'podazasz za ' hideoff6 = /hide off
/def -mregexp -Fp2 -t'nie jest w stanie wymknac sie stad' hideoff7 = /hide off
/def -mregexp -Fp2 -t'Nie jestes w stanie wymknac' sneakoff0 = /hide off
/def -mregexp -Fp2 -t'Nie jestes dowodca zadnej druzyny.' sneakoff1 = /hide off