/addworld mapper localhost 23923

/set _map_on=0
/set _map_paused=0
/def -ag -hBGTRIG
/def -ag -hACTIVITY

/def mapa =\
  /if ({*}=~'on') \
    /if (is_connected("mapper")==0) \
      /_map_connect%;\
      /if (is_connected("mapper")==0) \
        /set _map_on=0%;\
        /echo -p @{BCred}[MAP] Brak polaczenia z mapa.%;\
      /else \
        /set _map_on=1%;\
        /echo -p @{BCgreen}[MAP] Mapa wlaczona!%;\
      /endif%;\
    /else \
      /if ({_map_on}==1) \
        /echo -p @{BCblue}[MAP] Mapa juz jest wlaczona.%;\
      /else \
        /set _map_on=1%;\
        /echo -p @{BCgreen}[MAP] Mapa wlaczona!%;\
      /endif%;\
    /endif%;\
  /elseif ({*}=~'off') \
    /set _map_on=0%;\
    /echo -p @{BCred}[MAP] Mapa wylaczona.%;\
  /else \
    /if ({_map_on}=1) \
      /echo -p @{BCred}[MAP] Mapa wlaczona!%;\
    /else \
      /echo -p @{BCred}[MAP] Mapa wylaczona.%;\
    /endif%;\
  /endif

/def _map_connect = \
  /if (is_connected("mapper")==0) \
    /echo -p @{BCblue}[MAP] Probuje polaczyc sie z mapa..%; \
    /connect -b mapper%; \
  /endif

/def -mregexp -h'CONNECT mapper' _map_hooks_connect = \
  /echo -p @{BCgreen}[MAP] Polaczono z mapa! :)

/def -mregexp -h'DISCONNECT mapper' _map_hooks_disconnect = \
  /mapa off%; \
  /echo -p @{BCred}[MAP] Rozlaczano z mapa. :(

/def _map_send = \
  /if ({_map_on}==1 & {_map_paused}==0) \
    /send -wmapper %{*}%; \
  /endif

/def _map_bloker = \
  /_map_send map:revert

/def _map_create_bloker = \
  /_map_send map:undo

/def _map_teleport = \
  /if ({_map_room_id}!~{*}) \
    /_map_send lookup:%{*}%; \
  /endif

/def _map_go = \
  /_map_send navigate:%{*}%; \

/def -aL -mregexp -t'exit:rebind:([A-Z]+):(.*)' _map_exit_rebind = \
  /let helper=$[tolower({P1})]%;\
  /let helper=$[replace('dn','d',{helper})]%;\
  /let helper=$[replace('up','u',{helper})]%;\
  /set _map_rebind_exit_%{helper}=%{P2}

/set _map_custom_exits_counter=-1
/set _map_custom_exits_count=0

/def -aL -mregexp -t'exit:custom:(.*)' _map_exit_rebind_custom_array = \
  /set _map_custom_%{_map_custom_exits_count}=%{P1}%; \
  /set _map_custom_exits_count=$[_map_custom_exits_count+1]%; \
  /_map_custom_build%; \
  /_map_custom_show

/def -aL -mregexp -t'exit:end' _map_exit_end = \
  /_map_custom_build%; \
  /_map_custom_show

/def _map_rebind_clear = \
  /quote -S /unset `/listvar -s _map_rebind_exit_*

/def _map_custom_clear = \
  /set _map_custom_exits_counter=-1%; \
  /set _map_custom_exits_count=0%; \
  /set _map_custom_current=%; \
  /set _map_custom_all=%;\
  /_map_custom_show

/def _map_custom_switch = \
  /if ({_map_custom_exits_count} == 0) /return%; /endif%; \
  /set _map_custom_exits_counter=$[mod(_map_custom_exits_counter+1, _map_custom_exits_count)]%; \
  /let __exitp=_map_custom_%{_map_custom_exits_counter}%; \
  /let __exit=$(/listvar -v %{__exitp})%; \
  /set _map_custom_current=%{__exit}%; \
  /def showx=/echo -p #@{C%c_info}#@{n}# Command: @{C%c_info}%{__exit}@{n}.%;\
  /def x=/send -h %{__exit}

/def _map_custom_build = \
  /set _map_custom_all=%; \
  /for i 0 $[{_map_custom_exits_count}-1] \
    /let __exitp=_map_custom_%%{i}%%; \
    /let __exit=$$(/listvar -v %%{__exitp})%%; \
    /set _map_custom_all=%%{_map_custom_all}%%{__exit}%%; \
    /if ({i} < {_map_custom_exits_count}-1) /set _map_custom_all=%%{_map_custom_all}|%%; /endif%; \
  /_map_custom_switch

/def _map_custom_show = \
  /if ({_map_custom_exits_count} == 0) \
    /set status_exits=$[strrep("-", 60)]%; \
    /return%; \
  /endif%; \
  /let __exits=%{_map_custom_all}%; \
  /let __exits=$[replace({_map_custom_current}, strcat("@{BCbgblue}", {_map_custom_current}, "@{n}"), {__exits})]%; \
  /let __exits=$[replace("|", " | ", {__exits})]%; \
  /set status_exits=$[decode_attr(strcat(" ", {__exits}, " ", strrep("-", 60)))]%; \
  /let __exits=@{BCblue}[MAP]   @{n}| %{__exits} |

/def -aL -mregexp -t'set:(.*):(.*)' _map_set = \
  /set _map_%{P1}=%{P2}

/def -aL -mregexp -t'room:enter' _map_room_enter = \
  /_map_custom_clear%;\
  /_map_rebind_clear

/def -aL -mregexp -t'room:id:(.*)' _map_room_id = \
  /set _map_room_id=%{P1}

/def map_prompt_display = /echo -p %{1} -#-#-#-#-#-#- %{2}

/def -aL -mregexp -t'info:' _map_prompt_info = /test map_prompt_display("@{Crgb050}", "%{PR}")
/def -aL -mregexp -t'notice:' _map_prompt_notice = /test map_prompt_display("@{Crgb005}", "%{PR}")
/def -aL -mregexp -t'warn:' _map_prompt_warn = /test map_prompt_display("@{Crgb520}", "%{PR}")
/def -aL -mregexp -t'alert:' _map_prompt_alert = /test map_prompt_display("@{Crgb500}", "%{PR}")

/eval /def -mregexp -h'SEND ^(%{_map_standard_exits})$$' _map_hooks_ide_normal = \
  /if ({sneak} =~ "off" )\
    /send %%{P0}%%;\
    /hide off%%;\
  /elseif ({sneak} =~ "ON" )\
    /send przemknij %%{P0}%%;\
    /hide on%%;\
  /elseif ({sneak} =~ "GRP" )\
    /send przemknij z druzyna %%{P0}%%;\
    /hide on%%;\
  /endif%%;\
  /set lwgo=1%%;\
  /set lwlast=%%{P1}%%;\
  /if ({dowalkcmd} =~ "1")\
    /send %walkcmd%%;\
  /endif%%;\
  /def key_f12%%;\
  /def key_nkp5%%;\
  /_map_go exit:%%{P1}

/eval /def -mregexp -h'SEND ^((przemknij|p|pzd) (?:sie |)(?:z druzyna |))(%{_map_standard_exits})$$' _map_hooks_ide_sneak = \
  /send %%{P0}%%;\
  /set lwgo=1%%;\
  /set lwlast=%%{P3}%%;\
  /if ({dowalkcmd} =~ "1")\
    /send %walkcmd%%;\
  /endif%%;\
  /def key_f12%%;\
  /def key_nkp5%%;\
  /hide on%%;\
  /_map_go exit:%%{P3}

/eval /def -mregexp -h'SEND ^(%{_map_custom_exits})$$' _map_hooks_customy_normal = \
  /send %%{P0}%%;\
  /set lwgo=1%%;\
  /set lwlast=%%{P1}%%;\
  /def key_f12%%;\
  /def key_nkp5%%;\
  /hide off%%;\
  /_map_go custom:%%{P1}

/eval /def -mregexp -h'SEND ^((przemknij|p) (?:sie |)(?:z druzyna |))(%{_map_custom_exits})$$' _map_hooks_customy_sneak = \
  /send %%{P0}%%;\
  /set lwgo=1%%;\
  /set lwlast=%%{P3}%%;\
  /if ({dowalkcmd} =~ "1")\
    /send %walkcmd%%;\
  /endif%%;\
  /def key_f12%%;\
  /def key_nkp5%%;\
  /hide on%%;\
  /_map_go custom:%%{P3}

/eval /def -mregexp -h'SEND ^((%{_map_custom_exits_with_arg})( .*|))$$' _map_hooks_customy2_normal = \
  /send %%{P0}%%;\
  /set lwgo=1%%;\
  /set lwlast=%%{P1}%%;\
  /def key_f12%%;\
  /def key_nkp5%%;\
  /hide off%%;\
  /_map_go custom:%%{P1}

/eval /def -mregexp -Fp500 -t'(Wraz z (.*) podazasz|Podazasz)(?:| skradajac sie) za (.*?) (%{_map_follows_list})[.]$$' _map_podazam_za_kims_rozne = /_map_go follow:%%{P4}
/def -mregexp -Fp500 -t'(Wraz z (.*) podazasz|Podazasz)(?:| skradajac sie) za (.*) na gore' _map_podazam_za_kims_gora = /_map_go exit:gora
/def -mregexp -Fp500 -t'(Wraz z (.*) podazasz|Podazasz)(?:| skradajac sie) za (.*) na (dol|polnoc|poludnie|wschod|zachod|polnocny-wschod|polnocny-zachod|poludniowy-wschod|poludniowy-zachod)\.' _map_podazam_za_kims_standard = /_map_go exit:%{P4}

/def -mregexp -Fp500 -t'(odazasz.*(na tunel|do tunelu))' _map_podazam_dziwnosci_tunel = /_map_go custom:tunel

/def _map_convert_exit = \
  /if ({*}=~"z zachodu") \
    /echo wschod%; \
  /elseif ({*}=~"ze wschodu") \
    /echo zachod%; \
  /elseif ({*}=~"z polnocy") \
    /echo poludnie%; \
  /elseif ({*}=~"z poludnia") \
    /echo polnoc%; \
  /elseif ({*}=~"z polnocnego-zachodu") \
    /echo se%; \
  /elseif ({*}=~"z polnocnego-wschodu") \
    /echo sw%; \
  /elseif ({*}=~"z poludniowego-zachodu") \
    /echo ne%; \
  /elseif ({*}=~"z poludniowego-wschodu") \
    /echo nw%; \
  /elseif ({*}=~"z gory") \
    /echo dol%; \
  /elseif ({*}=~"z dolu") \
    /echo gora%; \
  /endif%; \

/def _map_idz_catch = \
  /purge _map_idz_move_trigger*%; \
  /eval /def -n1 -mregexp -Fp500 -t'Ruszasz (niespiesznie|marszem|truchtem|biegiem|szybkim biegiem) (%{_map_follows_list})\\\.' _map_idz_move_trigger_rozne = /set _map_paused=0%%%; /_map_go follow:%%%{P2}%%%;  /purge _map_idz_move_trigger*%; \
  /def -n1 -mregexp -Fp500 -t'Ruszasz (niespiesznie|marszem|truchtem|biegiem|szybkim biegiem) na gore\\.' _map_idz_move_trigger_gora = /_map_go exit:gora%%;  /purge _map_idz_move_trigger*%; \
  /def -n1 -mregexp -Fp500 -t'Ruszasz (niespiesznie|marszem|truchtem|biegiem|szybkim biegiem) na (dol|polnoc|poludnie|wschod|zachod|polnocny-wschod|polnocny-zachod|poludniowy-wschod|poludniowy-zachod)\\.' _map_idz_move_trigger_standard = /set _map_paused=0%%; /_map_go exit:%%{P2}%%; /purge _map_idz_move_trigger*%; \
  /def -n1 -mregexp -Fp500 -t' przybywa(ja|) za toba (.*)\.' _map_idz_move_trigger_przybywaja = /_map_go exit:$$(/_map_convert_exit %%{P2}%%)%%; /purge _map_idz_move_trigger*

/def -mregexp -Fp500 -t'Zaczynasz schodzic na dol\.' _map_wspinaczka_dol = \
  /set _map_wspinaczka=dol

/def -mregexp -Fp500 -t'(Wspomagajac sie lancuchem zaczynasz wspinac sie na gore w strone sciezki|Zaczynasz wspinac sie.*na gore)\.' _map_wspinaczka_gora = \
  /set _map_wspinaczka=gora

/def -mregexp -Fp500 -t'Odpadasz od sciany i lecisz w dol' _map_wspinaczka_spadam = \
  /if ({_map_wspinaczka}=~'gora') \
    /_map_bloker%; \
  /endif

/def _map_stagecoach_listen = \
  /purge _map_stagecoach_listen_trigger*%;\
  /def -q -n1 -F -h'SEND wyjscie' _map_stagecoach_listen_trigger = \
    /_map_teleport %%{_map_station}%;\
  /def -q -n1 -F -mregexp -t'podazasz za .* na zewnatrz, przez otwarte drzwi.' _map_stagecoach_listen_trigger_1 = \
    /_map_teleport %%{_map_station}

/def -mregexp -t'Wolisz nie probowac wysiasc z jadacego (dylizansu|wozu).' _map_stagecoach_revert = \
  /_map_bloker%;\
  /_map_stagecoach_listen

/set _map_standard_exits=\
  n|polnoc|\
  s|poludnie|\
  e|wschod|\
  w|zachod|\
  ne|polnocny-wschod|\
  se|poludniowy-wschod|\
  nw|polnocny-zachod|\
  sw|poludniowy-zachod|\
  u|gora|\
  d|dol